Rangsor: MAXHA, MINHA, NAGY, KICSI, MEDIÁN, RANG.EGY

Ha számokat nagyság szerint sorba állítasz, rangsort kapsz. Az Excel rangsorkezelő függvényeivel közvetlenül megkapod a rangsor elején vagy végén álló elemet, a középsőt, vagy egy adott szám helyezését, anélkül hogy a táblázatot rendeznéd.

A rangsorkezelő függvények

Függvény	Eredménye
`MAX`, `MIN`	a halmaz legnagyobb, illetve legkisebb száma
`MAXHA (MAXIFS)`, `MINHA (MINIFS)`	a feltételekkel szűkített halmaz legnagyobb, illetve legkisebb száma
`NAGY (LARGE)`, `KICSI (SMALL)`	a rangsor elejétől, illetve végétől adott helyen álló szám
`MEDIÁN (MEDIAN)`	a rangsor közepén álló szám
`RANG.EGY (RANK.EQ)`	egy szám helyezése a rangsorban

A példákban egy vizsga pontszámait használjuk:

	A	B	C
1	hallgató	pontszám	helyezés
2	Krisztián	149	3
3	Sebestyén	76	7
4	Gyöngyvér	181	2
5	Zsuzsanna	94	6
6	Franciska	128	4
7	Annamária	125	5
8	Krisztina	190	1

A C2 cella képlete: =RANG.EGY(B2;$B$2:$B$8), lefelé másolva.

MAX és MIN, feltétellel is

A =MAX(B2:B8) eredménye 190, a =MIN(B2:B8) eredménye 76. Legfeljebb 255 argumentumuk lehet. A hivatkozott cellákban álló szöveget, logikai értéket és üres cellát kihagyják; ha viszont logikai értéket közvetlenül argumentumként adsz meg, az IGAZ 1-et, a HAMIS 0-t ér.

MAXHA és MINHA

MAXHA(max_tartomány; kritériumtartomány1; kritérium1; [kritériumtartomány2; kritérium2]; …)

Ha nem a teljes halmazból, hanem csak a feltételeknek megfelelő sorokból keresed a legnagyobb vagy legkisebb értéket, a MAXHA és a MINHA a megoldás. Az első argumentum a vizsgált számok tartománya, utána tartomány-feltétel párok következnek, pontosan úgy, mint a SZUMHATÖBB-nél. A feltételek írásmódja is ugyanaz. (Ezek a függvények az Excel 2019-es és újabb verzióiban érhetők el.)

Egy gyár részlegeinek adatai: mekkora a legmagasabb termelékenység azoknál a részlegeknél, ahol legfeljebb 15-en dolgoznak, és legalább 26 darabot gyártottak?

	A	B	C	D
1	részleg	létszám	darabszám	termelékenység
2	A	17	34	80%
3	B	15	21	71%
4	C	14	33	73%
5	D	11	29	78%
6	E	13	26	75%
7	F	16	40	85%

Mindkét feltételnek a C, D és E részleg felel meg (kijelölve).

F2fx=MAXHA(D2:D7;B2:B7;"<=15";C2:C7;">=26")

Az eredmény 78% (D részleg). Az A és az F részleg termelékenysége magasabb, de ott 15-nél többen dolgoznak; a B részleg pedig csak 21 darabot gyártott. Ugyanezekkel a feltételekkel a MINHA eredménye 73%. A vizsgált és a feltételtartományoknak azonos méretűeknek kell lenniük.

NAGY és KICSI: a k-adik elem

NAGY(tömb; k)

KICSI(tömb; k)

A NAGY a k-adik legnagyobb, a KICSI a k-adik legkisebb számot adja vissza. A =NAGY(B2:B8;1) ugyanaz, mint a MAX, a =KICSI(B2:B8;1) ugyanaz, mint a MIN.

=NAGY(B2:B8;3): a harmadik legtöbb pont, 149.
=KICSI(B2:B8;2): a második legkevesebb pont, 94.

Toplista képlettel

A két függvényt leggyakrabban arra használod, hogy egy „dobogót” vagy toplistát készíts. A sorszámokat egy segédoszlopba írod, és a képletet lefelé másolod:

	E	F
1	helyezés	pontszám
2	1	190
3	2	181
4	3	149

Az F2 cella képlete: =NAGY($B$2:$B$8;E2), lefelé másolva.

F2fx=NAGY($B$2:$B$8;E2)

Az első argumentum abszolút hivatkozása rögzíti a vizsgált tartományt, a második argumentum relatív hivatkozása pedig soronként lépteti a sorszámot.

MEDIÁN: a középső érték

A MEDIÁN a rangsor közepén álló számot adja: a halmaz egyik fele nála nem nagyobb, a másik fele nem kisebb. Páratlan számú elemnél ez a középső elem, párosnál a két középső átlaga. A pontszámok mediánja =MEDIÁN(B2:B8) = 128 (76, 94, 125, 128, 149, 181, 190).

A medián jó határérték, ha egy csoportot két egyforma részre akarsz osztani. Példa: az év végén maradt egy kis jutalom, de csak a kollégák felének elég, és a főnök a hűséget díjazza. Kik kapják?

	A	B	C	D
1	név	belépett	jutalom	belépések mediánja
2	Mikó Ábel	2017.01.01	HAMIS	2014.02.20
3	Goda Ernő	2013.06.06	IGAZ
4	Cseh Adél	2015.05.27	HAMIS
5	Sebő Ádám	2014.11.06	HAMIS
6	Róka Géza	2010.11.04	IGAZ
7	Rácz Iván	2011.11.01	IGAZ

D2: =MEDIÁN(B2:B7); C2: =B2<$D$2, lefelé másolva.

Hat dátum van, ezért a medián a két középső (2013.06.06. és 2014.11.06.) átlaga: 2014.02.20. Aki ennél korábban lépett be, jutalmat kap: pontosan hárman, a csapat fele.

RANG.EGY: hányadik helyen áll?

RANG.EGY(szám; hiv; [sorrend])

A RANG.EGY megmondja, hányadik egy szám a rangsorban. Az első argumentum a vizsgált szám, a második a teljes tartomány (ezt rögzítsd abszolút hivatkozással, ha másolod a képletet), a harmadik a sorrend:

elhagyva vagy 0: csökkenő sorrend, a legnagyobb szám az 1. (pontszámoknál, eladásoknál ez kell);
1: növekvő sorrend, a legkisebb szám az 1. (például futóversenyen az időknél).

C2fx=RANG.EGY(B2;$B$2:$B$8)

Krisztián 149 pontja a 3. helyezés. Ha két szám egyenlő, ugyanazt a helyezést kapják, és a következő helyezés kimarad: ha ketten is 181 pontot értek volna el, mindketten 2. lennének, a következő pedig 4.

Tipp

A halmaz elemeinek számát a DARAB adja meg. Ha minden szám különböző, az utolsó helyezés éppen ennyi: itt =DARAB(B2:B8) = 7.

Összefoglalás

MAX, MIN: legnagyobb és legkisebb; MAXHA, MINHA: ugyanez tartomány-feltétel párokkal.
NAGY(tömb; k) és KICSI(tömb; k): a k-adik legnagyobb és legkisebb; toplistához abszolút tartománnyal másold.
MEDIÁN: a középső érték, páros elemszámnál a két középső átlaga; jó felező határ.
RANG.EGY(szám; hiv; [sorrend]): helyezés; 0 vagy elhagyva csökkenő, 1 növekvő sorrend.

Gyakorlás

Töltsd le a gyakorló munkafüzetet, és oldd meg a megadott munkalapok feladatait. A sárga cellákba kerülnek a képletek. Ha elakadsz, nézd meg a megoldást.

Összesítés és megszámlálás: gyakorló feladatok

Rangsor Osztályok rangsora büntetőpontok alapján: RANG.EGY, NAGY, KICSI, MEDIÁN, MAXHA, MINHA.

Feladatlap .xlsx, 22 kB Megoldás .xlsx, 24 kB

Ez volt a modul utolsó leckéje

Ellenőrizd a tudásodat a modul rövid kvízével: 6 kérdés, azonnali visszajelzéssel.

Modulkvíz indítása