7.3 lecke · 3/4 · kb. 5 perc
Megszámlálás: DARAB, DARAB2, DARABTELI, DARABHATÖBB
Az összeadás mellett a megszámlálás a leggyakoribb művelet: hány megrendelés jött, hányan fizettek már, hány tétel lépte túl a határt. Ebben a leckében megismered a DARAB függvénycsaládot.
A megszámláló függvények
| Függvény | Mit számol meg? |
|---|---|
DARAB (COUNT) | a számot tartalmazó cellákat |
DARAB2 (COUNTA) | a tartalommal rendelkező (nem üres) cellákat |
DARABÜRES (COUNTBLANK) | az üres cellákat |
DARABTELI (COUNTIF) | az egy feltételnek megfelelő cellákat |
DARABHATÖBB (COUNTIFS) | azokat a sorokat, ahol minden feltétel teljesül |
A lecke példáiban egy tanfolyami nyilvántartást használunk:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | név | tanfolyam | pontszám | befizetve |
| 2 | Hegyi Félix | Excel alap | 82 | 2025.02.03 |
| 3 | Szőke Petra | Excel haladó | 95 | |
| 4 | Kovács Dénes | Excel alap | 47 | 2025.02.10 |
| 5 | Takács Rita | Word | hiányzott | 2025.02.05 |
| 6 | Bodnár Imre | Excel haladó | 68 | |
| 7 | Fazekas Lili | Excel alap | 91 | 2025.02.12 |
DARAB, DARAB2, DARABÜRES
DARAB: a számok
A DARAB azokat a cellákat számolja, amelyekben szám áll. Számnak számít minden, amit az Excel számként tárol: a dátum és az idő is.
=DARAB(C2:C7)eredménye 5: a „hiányzott” szöveg nem számít.=DARAB(D2:D7)eredménye 4: a négy befizetési dátum mind szám.
A hivatkozott cellákban álló logikai értékeket (IGAZ, HAMIS) a DARAB kihagyja. A DARAB függvénynek is legfeljebb 255 argumentuma lehet, és nem tesz különbséget aközött, hogy a szám állandó vagy egy képlet eredménye.
DARAB2 és DARABÜRES: tele vagy üres?
Első ránézésre a két függvény egymás ellentéte: =DARAB2(A2:A7) eredménye 6 (minden névcella kitöltött), =DARABÜRES(D2:D7) eredménye 2 (két ember még nem fizetett). Van azonban egy fontos eltérés: nem ugyanazt tekintik üresnek.
| A | B | |
|---|---|---|
| 1 | koko | szöveg |
| 2 | 11 | szám |
| 3 | IGAZ | logikai érték |
| 4 | =HA(1<2;"") | |
| 5 | valóban üres |
Az A4 cellában képlet áll, amelynek eredménye üres szöveg (""): a cella üresnek látszik, de nem az.
| Képlet | Eredmény | Az A4 cellát… |
|---|---|---|
=DARABÜRES(A1:A5) | 2 | üresnek tekinti (nincs látható tartalma) |
=DARAB2(A1:A5) | 4 | nem üresnek tekinti (van benne képlet) |
A DARABÜRES-nek a láthatóság a mérce, a DARAB2-nek a kitöltöttség. Ezért a kettő összege itt 6, pedig csak 5 cella van. Ha a táblázatodban ""-t visszaadó képletek vannak, ezt mindig vedd figyelembe.
Jó tudni
A DARABÜRES csak egyetlen argumentumot fogad el, és az csak cella- vagy tartományhivatkozás lehet. A DARAB2-nek akár 255 argumentuma lehet, és állandót vagy képletet is kaphat: ezeket egyenként egy-egy tételnek számolja.
DARABTELI: számolás egy feltétellel
DARABTELI(tartomány; kritérium)A DARABTELI megszámolja a tartomány azon celláit, amelyek megfelelnek a feltételnek. A feltétel írásmódja pontosan ugyanaz, mint a SZUMHA-nál: idézőjel, relációs jelek, & a hivatkozáshoz, helyettesítő karakterek. A kis- és nagybetűt nem különbözteti meg.
| Kérdés | Képlet | Eredmény |
|---|---|---|
| Hányan járnak Excel alapra? | =DARABTELI(B2:B7;"Excel alap") | 3 |
| Hányan járnak bármilyen Excel tanfolyamra? | =DARABTELI(B2:B7;"Excel*") | 5 |
| Hányan nem Wordre járnak? | =DARABTELI(B2:B7;"<>Word") | 5 |
| Hányan értek el legalább 60 pontot? | =DARABTELI(C2:C7;">=60") | 4 |
| Hányan teljesítettek átlag felett? | =DARABTELI(C2:C7;">"&ÁTLAG(C2:C7)) | 3 |
| Hányan fizettek február 5-én vagy később? | =DARABTELI(D2:D7;">=2025.02.05") | 3 |
| Hányan nem fizettek még? | =DARABTELI(D2:D7;"") | 2 |
Az átlag a számokból 383 / 5 = 76,6, e fölött 82, 95 és 91 pont van.
Figyelem: a „nem egyenlő” az üreseket is számolja
A "<>alma" feltétel minden olyan cellát megszámol, amelyben nem „alma” áll. Az üres cellákban sem „alma” áll, ezért azok is beleszámítanak. Ha a tartomány alja üres, az eredmény meglepően nagy lehet.
Üres, nem üres, szöveg
"*": a szöveget tartalmazó cellák; a""-t visszaadó képlet is ide számít."": úgy számol, mint a DARABÜRES (a valóban üres és a""-t adó cellák)."<>": úgy számol, mint a DARAB2 (minden kitöltött cella, a""-t adó képlet is).
Trükk: az ismétlődések sorszámozása
A DARABTELI-vel azt is megállapíthatod, hogy egy elem hányadszor fordul elő a listában az adott sorig. A titok egy bővülő tartomány: az eleje rögzített, a vége relatív.
| A | B | C | |
|---|---|---|---|
| 1 | név | előfordulás | vizsgált tartomány |
| 2 | Éva | 1 | $A$2:A2 |
| 3 | Bendegúz | 1 | $A$2:A3 |
| 4 | Mihály | 1 | $A$2:A4 |
| 5 | Éva | 2 | $A$2:A5 |
| 6 | Katalin | 1 | $A$2:A6 |
| 7 | Bendegúz | 2 | $A$2:A7 |
| 8 | Éva | 3 | $A$2:A8 |
A B2 cella képlete: =DARABTELI($A$2:A2;A2), lefelé másolva.
Másoláskor a tartomány eleje az abszolút hivatkozás miatt marad A2, a vége soronként lép. A B8 cellában a képlet már =DARABTELI($A$2:A8;A8): az első hét név közül háromszor szerepel „Éva”. Ha csak az ismétlődéseket keresed, szűrj azokra a sorokra, ahol az érték nagyobb 1-nél.
DARABHATÖBB: számolás több feltétellel
DARABHATÖBB(kritériumtartomány1; kritérium1; [kritériumtartomány2; kritérium2]; …)Az argumentumok párban állnak: tartomány és a hozzá tartozó feltétel, legfeljebb 127 pár. A függvény soronként halad: először az összes tartomány első celláját nézi meg, mindegyiket a saját feltételével, aztán a másodikakat, és így tovább. Azokat a sorokat számolja meg, ahol minden feltétel teljesül.
Hányan járnak Excel tanfolyamra legalább 60 ponttal? Hegyi Félix (82), Szőke Petra (95), Bodnár Imre (68) és Fazekas Lili (91): az eredmény 4. Kovács Dénes Excelre jár, de 47 pontja kevés.
Hány Excel-tanfolyamos nem fizetett még? Szőke Petra és Bodnár Imre: 2.
Figyelem
A tartományoknak azonos méretűeknek és azonos tájolásúaknak kell lenniük (például mind a 2-7. sor egy-egy oszlopa). Ha nem azok, #ÉRTÉK! hibát kapsz.
Összefoglalás
DARAB: számok (dátum is);DARAB2: nem üres cellák;DARABÜRES: üres cellák.- A
""-t visszaadó képlet a DARAB2-nek nem üres, a DARABÜRES-nek üres. DARABTELI(tartomány; kritérium)a SZUMHA-val azonos feltételírást használ; a"<>…"az üres cellákat is számolja.=DARABTELI($A$2:A2;A2)bővülő tartománnyal sorszámozza az ismétlődéseket.DARABHATÖBB: tartomány-feltétel párok, azonos méretű tartományokkal.
Gyakorlás
Töltsd le a gyakorló munkafüzetet, és oldd meg a megadott munkalapok feladatait. A sárga cellákba kerülnek a képletek. Ha elakadsz, nézd meg a megoldást.
Összesítés és megszámlálás: gyakorló feladatok
- Hallgatók Hallgatók megszámlálása DARABTELI és DARABHATÖBB függvénnyel, helyettesítő karakterrel.
- Autóverseny Futamok jegyzőkönyve: DARAB2, DARAB, DARABÜRES és DARABTELI a starthoz, célba éréshez, kieséshez.